Is het mogelijk om in Excel een formule te maken voor het volgende?

Question

Is er een formule te maken voor het aantal keren winst, gelijkspel en verlies bij de volgende tabel (zie afbeelding)? De tabel links bevat de uitslagen van de wedstrijden. Rechts wil ik graag het aantal keren winst/gelijkspel/verlies van de desbetreffende landen.

Kan hierbij een formule worden gemaakt, of is dit niet mogelijk? Zo ja, wilt u deze formule in uw antwoord vermelden? De tabel links loopt van B17:F46.

 · Accepted Answer

Dat lukt niet met zomaar 1 formule. Maar het kan wel.
Maak een verborgen kolom naast de landennaam (tussen kolommen C/D en tussen kolommen E/F) waar je samen met de naam van het betreffende land een W, V of G laat verschijnen. Da's te doen met een formule
=IF(D17>E17;D16&"_W";IF(D17=E17;D16&"_G";D16&"_V")).
Die rij wordt dan vanzelf gevuld met waarden zoals "Kroatie_W" wat aangeeft dat Kroatie won.
Daarna vul je de rechtertabel met COUNT.IF-functies, die tellen hoe vaak die termen verschenen zijn COUNT.IF(D17:G46;"Belgie_W")
Ik snap niet wat je bedoelt met de tellingen DV, DW en DS maar die moet je op dezelfde manier wel kunnen maken.

 · Answer

Natuurlijk kan dat:

Met een beetje slim gebruiken van de SOMALS functie is dat mogelijk

In I17 invullen:
=SOMPRODUCT(($C$17:$C$46=H17)*1;($D$17:$D$46>$E$17:$E$46)*1)
+SOMPRODUCT(($F$17:$F$46=H17)*1;($D$17:$D$46<$E$17:$E$46)*1)

In J17 invullen:
=SOMPRODUCT(($C$17:$C$46=H17)*1;($D$17:$D$46=$E$17:$E$46)*1;($D$17:$D$46<>"")*1)
+SOMPRODUCT(($F$17:$F$46=H17)*1;($D$17:$D$46=$E$17:$E$46)*1;($D$17:$D$46<>"")*1)

In K17 invullen:
=SOMPRODUCT(($C$17:$C$46=H17)*1;($D$17:$D$46<$E$17:$E$46)*1)
+SOMPRODUCT(($F$17:$F$46=H17)*1;($D$17:$D$46>$E$17:$E$46)*1)

En dan die formules voor alle landen naar beneden kopieren.

Ik zal van de middelste even uitleggen wat die doet

($C$17:$C$46=H17)*1 kijkt of de thuislanden overeenkomen, daar komt in principe een vector uit met de waarden WAAR en ONWAAR. Door die vector met 1 te vermenigvuldigen kan je er mee rekenen

($D$17:$D$46=$E$17:$E$46)*1 kijkt of het gelijkspel is, als dat zo is komt op die plek van de vector een 1tje te staan, anders een 0.

($D$17:$D$46<>"")*1 kijkt of er een uitslag is ingevuld, als dat zo is komt op die plek van de vector een 1tje te staan, anders een 0.

SOMPRODUCT(); vermenigvuldigd al die vectoren en telt ze vervolgens op.
Doordat we die vectoren slim hebben gekozen maakt deze formule dus eerst een
vector met o-en en 1-en, waarbij er 1-en staan als het het juiste land is EN er is gelijk gespeeld EN er is gespeeld, en telt dan al die juiste combinaties op.

Het tweede deel van de formule doet precies hetzelfde, maar dan geredeneerd vanuit de uitlanden.

Is het mogelijk om in Excel een formule te maken voor het volgende?

Het beste antwoord

Andere antwoorden (1)

Weet jij het beter..?